# Collinear spin and magnetic systems

In this example we consider iron in the BCC phase. To show that this material is ferromagnetic we will model it once allowing collinear spin polarization and once without and compare the resulting SCF energies. In particular the ground state can only be found if collinear spins are allowed.

First we setup BCC iron without spin polarization using a single iron atom inside the unit cell.

```
using DFTK
a = 5.42352 # Bohr
lattice = a / 2 * [[-1 1 1];
[ 1 -1 1];
[ 1 1 -1]]
Fe = ElementPsp(:Fe, psp=load_psp("hgh/lda/Fe-q8.hgh"))
atoms = [Fe => [zeros(3)]];
```

To get the ground-state energy we use an LDA model and rather moderate discretisation parameters.

```
kgrid = [3, 3, 3] # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 15 # kinetic energy cutoff in Hartree
model_nospin = model_LDA(lattice, atoms, temperature=0.01)
basis_nospin = PlaneWaveBasis(model_nospin; kgrid, Ecut)
scfres_nospin = self_consistent_field(basis_nospin, tol=1e-6, mixing=KerkerMixing());
```

n Free energy Eₙ-Eₙ₋₁ ρout-ρin α Diag --- --------------- --------- -------- ---- ---- 1 -16.64708235066 NaN 3.28e-01 0.80 5.2 2 -16.64775194404 -6.70e-04 7.78e-02 0.80 1.0 3 -16.64782698992 -7.50e-05 3.18e-03 0.80 2.2 4 -16.64783331991 -6.33e-06 1.57e-03 0.80 3.5 5 -16.64783428757 -9.68e-07 2.01e-04 0.80 2.0

`scfres_nospin.energies`

Energy breakdown (in Ha): Kinetic 15.9236840 AtomicLocal -5.0708563 AtomicNonlocal -5.2218337 Ewald -21.4723040 PspCorrection 1.8758831 Hartree 0.7797856 Xc -3.4439037 Entropy -0.0182893 total -16.647834287567

Since we did not specify any initial magnetic moment on the iron atom, DFTK will automatically assume that a calculation with only spin-paired electrons should be performed. As a result the obtained ground state features no spin-polarization.

Now we repeat the calculation, but give the iron atom an initial magnetic moment. For specifying the magnetic moment pass the desired excess of spin-up over spin-down electrons at each centre to the `Model`

and the guess density functions. In this case we seek the state with as many spin-parallel $d$-electrons as possible. In our pseudopotential model the 8 valence electrons are 2 pair of $s$-electrons, 1 pair of $d$-electrons and 4 unpaired $d$-electrons giving a desired magnetic moment of `4`

at the iron centre. The structure (i.e. pair mapping and order) of the `magnetic_moments`

array needs to agree with the `atoms`

array and `0`

magnetic moments need to be specified as well.

`magnetic_moments = [Fe => [4, ]];`

Unlike all other quantities magnetisation and magnetic moments in DFTK are given in units of the Bohr magneton $μ_B$, which in atomic units has the value $\frac{1}{2}$. Since $μ_B$ is (roughly) the magnetic moment of a single electron the advantage is that one can directly think of these quantities as the excess of spin-up electrons or spin-up electron density.

We repeat the calculation using the same model as before. DFTK now detects the non-zero moment and switches to a collinear calculation.

```
model = model_LDA(lattice, atoms, magnetic_moments=magnetic_moments, temperature=0.01)
basis = PlaneWaveBasis(model; Ecut, kgrid)
ρ0 = guess_density(basis, magnetic_moments)
scfres = self_consistent_field(basis, tol=1e-6; ρ=ρ0, mixing=KerkerMixing());
```

n Free energy Eₙ-Eₙ₋₁ ρout-ρin Magnet α Diag --- --------------- --------- -------- ------ ---- ---- 1 -16.65996692006 NaN 3.11e-01 2.620 0.80 4.5 2 -16.66626204162 -6.30e-03 6.98e-02 2.428 0.80 1.0 3 -16.66694852402 -6.86e-04 9.40e-03 2.349 0.80 2.9 4 -16.66698689714 -3.84e-05 4.33e-03 2.320 0.80 3.0 5 -16.66699449406 -7.60e-06 1.77e-03 2.309 0.80 2.2 6 -16.66699629730 -1.80e-06 5.74e-04 2.300 0.80 1.5 7 -16.66699651922 -2.22e-07 4.18e-05 2.297 0.80 1.5

`scfres.energies`

Energy breakdown (in Ha): Kinetic 16.3014674 AtomicLocal -5.2260053 AtomicNonlocal -5.4135491 Ewald -21.4723040 PspCorrection 1.8758831 Hartree 0.8201249 Xc -3.5395357 Entropy -0.0130778 total -16.666996519221

DFTK does not store the `magnetic_moments`

inside the `Model`

, but only uses them to determine the lattice symmetries. This step was taken to keep `Model`

(which contains the physical model) independent of the details of the numerical details such as the initial guess for the spin density.

In direct comparison we notice the first, spin-paired calculation to be a little higher in energy

```
println("No magnetization: ", scfres_nospin.energies.total)
println("Magnetic case: ", scfres.energies.total)
println("Difference: ", scfres.energies.total - scfres_nospin.energies.total);
```

No magnetization: -16.64783428756724 Magnetic case: -16.666996519221357 Difference: -0.01916223165411779

Notice that with the small cutoffs we use to generate the online documentation the calculation is far from converged. With more realistic parameters a larger energy difference of about 0.1 Hartree is obtained.

The spin polarization in the magnetic case is visible if we consider the occupation of the spin-up and spin-down Kohn-Sham orbitals. Especially for the $d$-orbitals these differ rather drastically. For example for the first $k$-point:

```
iup = 1
idown = iup + length(scfres.basis.kpoints) ÷ 2
@show scfres.occupation[iup][1:7]
@show scfres.occupation[idown][1:7];
```

(scfres.occupation[iup])[1:7] = [1.0, 0.9999988143147648, 0.99999881430771, 0.9999988142964183, 0.9585766961952732, 0.9585766175560726, 1.154421493630566e-29] (scfres.occupation[idown])[1:7] = [1.0, 0.8324620121769625, 0.8324610460509584, 0.8324600699835081, 7.829176991962237e-6, 7.829058991020714e-6, 1.5495002528888744e-32]

Similarly the eigenvalues differ

```
@show scfres.eigenvalues[iup][1:7]
@show scfres.eigenvalues[idown][1:7];
```

(scfres.eigenvalues[iup])[1:7] = [-0.06926924003401098, 0.3568792420067976, 0.35687930150773295, 0.3568793967383048, 0.46191506748113675, 0.4619150872857833, 1.1596448105764177] (scfres.eigenvalues[idown])[1:7] = [-0.030403122671994465, 0.47729935236724763, 0.477299421638821, 0.47729949162287555, 0.6109075804185642, 0.6109077311403511, 1.2257790322235178]

For collinear calculations the `kpoints`

field of the `PlaneWaveBasis`

object contains each $k$-point coordinate twice, once associated with spin-up and once with down-down. The list first contains all spin-up $k$-points and then all spin-down $k$-points, such that `iup`

and `idown`

index the same $k$-point, but differing spins.

We can observe the spin-polarization by looking at the density of states (DOS) around the Fermi level, where the spin-up and spin-down DOS differ.

```
using Plots
plot_dos(scfres)
```

Similarly the band structure shows clear differences between both spin components.

```
using Unitful
using UnitfulAtomic
plot_bandstructure(scfres; kline_density=6)
```